Chapter Contents Previous Next
 The PROBIT Procedure

## Example 54.2: Multilevel Response

In this example, two preparations, a standard preparation and a test preparation, are each given at several dose levels to groups of insects. The symptoms are recorded for each insect within each group, and two multilevel probit models are fit. Because the natural sort order of the three levels is not the same as the response order, the ORDER=DATA option is specified in the PROC statement to get the desired order.

The following statements produce Output 54.2.1:

```   data multi;
input Prep \$ Dose Symptoms \$ N;
LDose=log10(Dose);
if Prep='test' then PrepDose=LDose;
else PrepDose=0;
datalines;
stand     10      None       33
stand     10      Mild        7
stand     10      Severe     10
stand     20      None       17
stand     20      Mild       13
stand     20      Severe     17
stand     30      None       14
stand     30      Mild        3
stand     30      Severe     28
stand     40      None        9
stand     40      Mild        8
stand     40      Severe     32
test      10      None       44
test      10      Mild        6
test      10      Severe      0
test      20      None       32
test      20      Mild       10
test      20      Severe     12
test      30      None       23
test      30      Mild        7
test      30      Severe     21
test      40      None       16
test      40      Mild        6
test      40      Severe     19
;

proc probit order=data;
class Prep Symptoms;
nonpara: model Symptoms=Prep LDose PrepDose / lackfit;
weight N;
parallel: model Symptoms=Prep LDose / lackfit;
weight N;
title 'Probit Models for Symptom Severity';
run;
```

The first model uses the PrepDose variable to allow for nonparallelism between the dose response curves for the two preparations. The results of this first model indicate that the parameter for the PrepDose variable is not significant, having a Wald chi-square of 0.73. Also, since the first model is a generalization of the second, a likelihood ratio test statistic for this same parameter can be obtained by multiplying the difference in log likelihoods between the two models by 2. The value obtained, 2 ×(-345.94 - (-346.31)), is 0.73. This is in close agreement with the Wald chi-square from the first model. The lack-of-fit test statistics for the two models do not indicate a problem with either fit.

Output 54.2.1: Multilevel Response: PROC PROBIT

 Probit Models for Symptom Severity

 Probit Procedure

 Class Level Information Name Levels Values Symptoms 3 None Mild Severe Prep 2 stand test

 Probit Models for Symptom Severity

 Probit Procedure

 Model Information Data Set WORK.MULTI Dependent Variable Symptoms Weight Variable N Number of Observations 23 Name of Distribution NORMAL Log Likelihood -345.9401767

 Weighted FrequencyCounts for the OrderedResponse Categories Level Count None 188 Mild 60 Severe 139

 Goodness-of-Fit Tests Statistic Value DF Pr > ChiSq Pearson Chi-Square 12.7930 11 0.3071 L.R. Chi-Square 15.7869 11 0.1492

 Response-Covariate Profile Response Levels 3 Number of Covariate Values 8

 Probit Models for Symptom Severity

 Probit Procedure

 Analysis of Parameter Estimates Variable DF Estimate Standard Error Chi-Square Pr > ChiSq Label Intercept 1 3.80803 0.62517 37.1030 <.0001 Intercept Prep 1 2.3568 0.1247 1 -1.25728 0.81897 2.3568 0.1247 stand 0 0 0 . . test LDose 1 -2.15120 0.39088 30.2874 <.0001 PrepDose 1 -0.50722 0.59449 0.7279 0.3935 Inter.2 1 0.46844 0.05591 Mild

 Probit Models for Symptom Severity

 Probit Procedure

 Class Level Information Name Levels Values Symptoms 3 None Mild Severe Prep 2 stand test

 Probit Models for Symptom Severity

 Probit Procedure

 Model Information Data Set WORK.MULTI Dependent Variable Symptoms Weight Variable N Number of Observations 23 Name of Distribution NORMAL Log Likelihood -346.306141

 Weighted FrequencyCounts for the OrderedResponse Categories Level Count None 188 Mild 60 Severe 139

 Goodness-of-Fit Tests Statistic Value DF Pr > ChiSq Pearson Chi-Square 12.7864 12 0.3848 L.R. Chi-Square 16.5189 12 0.1686

 Response-Covariate Profile Response Levels 3 Number of Covariate Values 8

 Probit Models for Symptom Severity

 Probit Procedure

 Analysis of Parameter Estimates Variable DF Estimate Standard Error Chi-Square Pr > ChiSq Label Intercept 1 3.41482 0.41260 68.4962 <.0001 Intercept Prep 1 20.3304 <.0001 1 -0.56752 0.12586 20.3304 <.0001 stand 0 0 0 . . test LDose 1 -2.37213 0.29495 64.6824 <.0001 Inter.2 1 0.46780 0.05584 Mild

The negative coefficient associated with LDose indicates that the probability of having no symptoms (Symptoms='None') or no or mild symptoms (Symptoms='None' or Symptoms='Mild') decreases as LDose increases; that is, the probability of a severe symptom increases with LDose. This association is apparent for both treatment groups.

The negative coefficient associated with the standard treatment group (Prep = stand) indicates that the standard treatment is associated with more severe symptoms across all ldose values.

 Chapter Contents Previous Next Top