Chapter Contents Previous Next
 Details of the FACTEX Procedure

## Example 15.12: Replicated Blocked Design with Partial Confounding

 See FACTEX15 in the SAS/QC Sample Library

In an unreplicated blocked design, the interaction effect that is confounded with the block effect cannot be estimated. You can replicate the experiment so that a different interaction effect is confounded in each replicate. This enables you to obtain information about an interaction effect from the replicate(s) in which it is not confounded.

For example, consider a 23 design with factors A, B, and C arranged in two blocks. Suppose you decide to run four replicates of the design. By constructing the design sequentially, you can choose the effects to be estimated in each replicate depending on the interaction confounded with the block effect in the other replicates.

In the first replicate, you specify only that the main effects are to be estimable. The following statements generate an eight-run two-level design arranged in two blocks:

```   proc factex;
factors a b c;
blocks nblocks=2;
model est=(a b c);
examine confounding aliasing;
output out=rep1 blockname=block nvals=(1 2);
run;
```

The alias structure and the confounding scheme are listed in Output 15.12.1. The highest order interaction A*B*C is confounded with the block effect. The design, with recoded block levels, is saved in a dataset named REP1.

Output 15.12.1: Confounding Rule and Alias Structure for Replicate 1

 The FACTEX Procedure

 Block Pseudo-factor ConfoundingRules [B1] = a*b*c

 The FACTEX Procedure

 Aliasing Structure a b c a*b a*c b*c

If you were to analyze this replicate by itself, you could not determine whether an effect is due to A*B*C or the block effect. You can construct a second replicate that confounds a different interaction effect with the block effect. Since the FACTEX procedure is interactive, simply submit the following statements to generate the second replicate:

```      model est=(a b c a*b*c);
output out=rep2
blockname=block nvals=(3 4);
run;
```

The alias structure and the confounding scheme for the second replicate are listed in Output 15.12.2. The interaction A*B*C is free of any aliases, but now the two-factor interaction B*C is confounded with the block effect.

Output 15.12.2: Confounding Rule and Alias Structure for Replicate 2

 The FACTEX Procedure

 Block Pseudo-factor ConfoundingRules [B1] = b*c

 The FACTEX Procedure

 Aliasing Structure a b c a*b a*c [B] = b*c a*b*c

To estimate the interaction B*C with the third replicate, submit the following statements (immediately after the preceding statements):
```      model est=(a b c a*b*c b*c);
output out=rep3 blockname=block nvals=(5 6);
run;
```

The alias structure and confounding rules are shown in Output 15.12.3. The interaction B*C is free of aliases, but the interaction A*C is confounded with the block effect.

Output 15.12.3: Confounding Rule and Alias Structure for Replicate 3

 The FACTEX Procedure

 Block Pseudo-factor ConfoundingRules [B1] = a*c

 The FACTEX Procedure

 Aliasing Structure a b c a*b [B] = a*c b*c a*b*c

Finally, to estimate the interaction effect A*C with the fourth replicate, submit the following statements:
```      model est=(a b c a*b*c b*c a*c);
output out=rep4 blockname=block nvals=(7 8);
run;
```

The alias structure and confounding rules are displayed in Output 15.12.4.

Output 15.12.4: Confounding Rule and Alias Structure for Replicate 4

 The FACTEX Procedure

 Block Pseudo-factor ConfoundingRules [B1] = a*b

 The FACTEX Procedure

 Aliasing Structure a b c [B] = a*b a*c b*c a*b*c

When combined, these four replicates give full information on the main effects and three-quarter information on each of the interactions. The following statements combine the four replicates:
```   data combine;
set rep1 rep2 rep3 rep4;
run;

proc print data=combine;
run;
```

The final design is saved in the data set COMBINE. A listing of this data set is shown in Output 15.12.5.

Output 15.12.5: Combined Design

 Obs block a b c 1 1 -1 -1 -1 2 1 -1 1 1 3 1 1 -1 1 4 1 1 1 -1 5 2 -1 -1 1 6 2 -1 1 -1 7 2 1 -1 -1 8 2 1 1 1 9 3 -1 -1 1 10 3 -1 1 -1 11 3 1 -1 1 12 3 1 1 -1 13 4 -1 -1 -1 14 4 -1 1 1 15 4 1 -1 -1 16 4 1 1 1 17 5 -1 -1 1 18 5 -1 1 1 19 5 1 -1 -1 20 5 1 1 -1 21 6 -1 -1 -1 22 6 -1 1 -1 23 6 1 -1 1 24 6 1 1 1 25 7 -1 1 -1 26 7 -1 1 1 27 7 1 -1 -1 28 7 1 -1 1 29 8 -1 -1 -1 30 8 -1 -1 1 31 8 1 1 -1 32 8 1 1 1

 Chapter Contents Previous Next Top