Chapter Contents

Previous

Next

Example 28.11: Analysis of a Screening Design

   data HalfFraction;
      input power flow pressure gap rate;
      datalines;
   0.8   4.5 125 275     550
   0.8   4.5 200 325     650
   0.8 550.0 125 325     642
   0.8 550.0 200 275     601
   1.2   4.5 125 325     749
   1.2   4.5 200 275    1052
   1.2 550.0 125 275    1075
   1.2 550.0 200 325     729
   ;

Notice that each of the factors has just two values. This is a common experimental design when the intent is to screen from the many factors that might affect the response the few that actually do. Since there are 2⁴=16 different possible settings of four two-level factors, this design with only eight runs is called a "half fraction." The eight runs are chosen specifically to provide unambiguous information on main effects at the cost of confounding interaction effects with each other.

One way to analyze this data is simply to use PROC GLM to compute an analysis of variance, including both main effects and interactions in the model. The following statements demonstrate this approach.

   proc glm data=HalfFraction;
      class power flow pressure gap;
      model rate=power|flow|pressure|gap@2;
   run;

The `@2' notation on the model statement includes all main effects and two-factor interactions between the factors. The output is shown in Output 28.11.1.

Another thing to notice in Output 28.11.1 is the difference between the Type I and Type III ANOVA tables. The rows corresponding to main effects in each are the same, but no Type III interaction tests are estimable, while some Type I interaction tests are estimable. This indicates that there is aliasing in the design: some interactions are completely confounded with each other.

In order to analyze this confounding, you should examine the aliasing structure of the design using the ALIASING option in the MODEL statement. Before doing so, however, it is advisable to code the design, replacing low and high levels of each factor with the values -1 and +1, respectively. This puts each factor on an equal footing in the model and makes the aliasing structure much more interpretable. The following statements code the data, creating a new data set named Coded.

   data Coded; set HalfFraction;
      power    = -1*(power   =0.80) + 1*(power   =1.20);
      flow     = -1*(flow    =4.50) + 1*(flow    =550 );
      pressure = -1*(pressure=125 ) + 1*(pressure=200 );
      gap      = -1*(gap     =275 ) + 1*(gap     =325 );
   run;

The following statements use the GLM procedure to reanalyze the coded design, displaying the parameter estimates as well as the functions of the parameters that they each estimate.

   proc glm data=Coded;
      model rate=power|flow|pressure|gap@2 / solution aliasing;
   run;

The parameter estimates table is shown in Output 28.11.2.

Fortunately, eight more runs are available for this experiment (the other half fraction.) The following statements create a data set containing these extra runs and add it to the previous eight, resulting in a full 2⁴=16 run replicate. Then PROC GLM displays the analysis of variance again.

   data OtherHalf;
      input power flow pressure gap rate;
      datalines;
   0.8   4.5 125 325     669
   0.8   4.5 200 275     604
   0.8 550.0 125 275     633
   0.8 550.0 200 325     635
   1.2   4.5 125 275    1037
   1.2   4.5 200 325     868
   1.2 550.0 125 325     860
   1.2 550.0 200 275    1063
   ;
   data FullRep;
      set HalfFraction OtherHalf;
   run;

   proc glm data=FullRep;
      class power flow pressure gap;
      model rate=power|flow|pressure|gap@2;
   run;

The results are displayed in Output 28.11.3.

With sixteen runs, the analysis of variance tells the whole story: all effects are estimable and there are five degrees of freedom left over to estimate the underlying error. The main effects of power and gap and their interaction are all significant, and no other effects are. Notice that the Type I and Type III ANOVA tables are the same; this is because the design is orthogonal and all effects are estimable.

This example illustrates the use of the GLM procedure for the model analysis of a screening experiment. Typically, there is much more involved in performing an experiment of this type, from selecting the design points to be studied to graphically assessing significant effects, optimizing the final model, and performing subsequent experimentation. Specialized tools for this are available in SAS/QC software, in particular the ADX Interface and the FACTEX and OPTEX procedures. Refer to SAS/QC User's Guide, Version 7, First Edition for more information.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.