Chapter Contents
Chapter Contents
Previous
Previous
Next
Next
The FACTOR Procedure

Input Data Set

The FACTOR procedure can read an ordinary SAS data set containing raw data or a special data set specified as a TYPE=CORR, TYPE=UCORR, TYPE=SSCP, TYPE=COV, TYPE=UCOV, or TYPE=FACTOR data set containing previously computed statistics. A TYPE=CORR data set can be created by the CORR procedure or various other procedures such as the PRINCOMP procedure. It contains means, standard deviations, the sample size, the correlation matrix, and possibly other statistics if it is created by some procedure other than PROC CORR. A TYPE=COV data set is similar to a TYPE=CORR data set but contains a covariance matrix. A TYPE=UCORR or TYPE=UCOV data set contains a correlation or covariance matrix that is not corrected for the mean. The default VAR variable list does not include Intercept if the DATA= data set is TYPE=SSCP. If the Intercept variable is explicitly specified in the VAR statement with a TYPE=SSCP data set, the NOINT option is activated. A TYPE=FACTOR data set can be created by the FACTOR procedure and is described in "Output Data Sets" .

If your data set has many observations and you plan to run FACTOR several times, you can save computer time by first creating a TYPE=CORR data set and using it as input to PROC FACTOR.

   proc corr data=raw out=correl;     /* create TYPE=CORR data set */
   proc factor data=correl method=ml; /* maximum likelihood        */
   proc factor data=correl;           /* principal components      */

The data set created by the CORR procedure is automatically given the TYPE=CORR data set option, so you do not have to specify TYPE=CORR. However, if you use a DATA step with a SET statement to modify the correlation data set, you must use the TYPE=CORR attribute in the new data set. You can use a VAR statement with PROC FACTOR when reading a TYPE=CORR data set to select a subset of the variables or change the order of the variables.

Problems can arise from using the CORR procedure when there are missing data. By default, PROC CORR computes each correlation from all observations that have values present for the pair of variables involved (pairwise deletion). The resulting correlation matrix may have negative eigenvalues. If you specify the NOMISS option with the CORR procedure, observations with any missing values are completely omitted from the calculations (listwise deletion), and there is no danger of negative eigenvalues.

PROC FACTOR can also create a TYPE=FACTOR data set, which includes all the information in a TYPE=CORR data set, and use it for repeated analyses. For a TYPE=FACTOR data set, the default value of the METHOD= option is PATTERN. The following statements produce the same PROC FACTOR results as the previous example:

   proc factor data=raw method=ml outstat=fact; /* max. likelihood */
   proc factor data=fact method=prin;      /* principal components */

You can use a TYPE=FACTOR data set to try several different rotation methods on the same data without repeatedly extracting the factors. In the following example, the second and third PROC FACTOR statements use the data set fact created by the first PROC FACTOR statement:

   proc factor data=raw outstat=fact; /* principal components */
   proc factor rotate=varimax;        /* varimax rotation     */
   proc factor rotate=quartimax;      /* quartimax rotation   */

You can create a TYPE=CORR, TYPE=UCORR, or TYPE=FACTOR data set in a DATA step. Be sure to specify the TYPE= option in parentheses after the data set name in the DATA statement and include the _TYPE_ and _NAME_ variables. In a TYPE=CORR data set, only the correlation matrix (_TYPE_='CORR') is necessary. It can contain missing values as long as every pair of variables has at least one nonmissing value.

   data correl(type=corr);
      _TYPE_='CORR';
      input _NAME_ $ x y z;
      datalines;
   x  1.0  .   .
   y   .7 1.0  .
   z   .5  .4 1.0
   ;
   proc factor;
   run;

You can create a TYPE=FACTOR data set containing only a factor pattern (_TYPE_='PATTERN') and use the FACTOR procedure to rotate it.

   data pat(type=factor);
      _TYPE_='PATTERN';
      input _NAME_ $ x y z;
      datalines;
   factor1  .5  .7  .3
   factor2  .8  .2  .8
   ;
   proc factor rotate=promax prerotate=none;
   run;

If the input factors are oblique, you must also include the interfactor correlation matrix with _TYPE_='FCORR'.

   data pat(type=factor);
      input _TYPE_ $ _NAME_ $ x y z;
      datalines;
   pattern factor1  .5  .7  .3
   pattern factor2  .8  .2  .8
   fcorr   factor1 1.0  .2  .
   fcorr   factor2  .2 1.0  .
   ;
   proc factor rotate=promax prerotate=none;
   run;

Some procedures, such as the PRINCOMP and CANDISC procedures, produce TYPE=CORR or TYPE=UCORR data sets containing scoring coefficients (_TYPE_='SCORE' or _TYPE_= 'USCORE'). These coefficients can be input to PROC FACTOR and rotated by using the METHOD=SCORE option. The input data set must contain the correlation matrix as well as the scoring coefficients.

   proc princomp data=raw n=2 outstat=prin;
   run;
   proc factor data=prin method=score rotate=varimax;
   run;

Chapter Contents
Chapter Contents
Previous
Previous
Next
Next
Top
Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.