Chapter Contents

Previous

Next

Example 20.5: Log-Linear Model, Structural and Sampling Zeros

In a population of six squirrel monkeys, the joint distribution of genital display with respect to active or passive role was observed. The data are from Fienberg (1980, Table 8-2). Since a monkey cannot have both the active and passive roles in the same interaction, the diagonal cells of the table are structural zeros. See Agresti (1990) for more information on the quasi-independence model. Since there is only one population, the structural zeros are automatically deleted by PROC CATMOD. The sampling zeros are replaced in the DATA step by some positive number close to zero (1E-20). Also, the row for Monkey T is deleted since it contains all zeros; therefore, the cell frequencies predicted by a model of independence are also zero. In addition, the CONTRAST statement compares the behavior of the two monkeys labeled U and V. The following statements produce Output 20.5.1 through Output 20.5.8:

   title 'Behavior of Squirrel Monkeys';
   data Display;
      input Active $ Passive $ wt @@;
      if Active ne 'T';
      if Active ne Passive then 
         if wt=0 then wt=1e-20;
      datalines;
   R R  0   R S  1   R T  5   R U  8   R V  9   R W  0
   S R 29   S S  0   S T 14   S U 46   S V  4   S W  0
   T R  0   T S  0   T T  0   T U  0   T V  0   T W  0
   U R  2   U S  3   U T  1   U U  0   U V 38   U W  2
   V R  0   V S  0   V T  0   V U  0   V V  0   V W  1
   W R  9   W S 25   W T  4   W U  6   W V 13   W W  0
   ;

   proc catmod data=Display;
      weight wt;
      model Active*Passive=_response_
            / freq pred=freq noparm noresponse oneway;
      loglin Active Passive;
      contrast 'Passive, U vs. V' Passive 0 0 0 1 -1;
      contrast 'Active,  U vs. V' Active  0 0 1 -1;
      title2 'Test Quasi-Independence for the Incomplete Table';
   quit;

Structural and Sampling Zeros with Raw Data

1. Run PROC FREQ on the raw data. In the TABLES statement, list all dependent and independent variables separated by asterisks and use the SPARSE option and the OUT= option. This creates an output data set that contains all possible zero frequencies.
2. Use a DATA step to change the zero frequencies associated with sampling zeros to a small value, such as 1E-20.
3. Use the resulting data set as input to PROC CATMOD, and specify the statement WEIGHT COUNT to use adjusted frequencies.

   proc freq data=RawDisplay;
      tables Active*Passive / sparse out=Combos noprint;
   run;

   data Combos2;
      set Combos;
      if Active ne 'T';
      if Active ne Passive then 
         if count=0 then count=1e-20;
   run;

   proc catmod data=Combos2;
      weight count;
      model Active*Passive=_response_
            / freq pred=freq noparm noresponse;
      loglin Active Passive;
   quit;

The first IF statement in the DATA step is needed only for this particular example; since observations for Monkey T were deleted from the Display data set, they also need to be deleted from Combos2.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.