Example 34.2: Specifying Standard Average Proportion

NPCHART Statement

Example 34.2: Specifying Standard Average Proportion

See SHWNP3 in the SAS/QC Sample Library

In some situations, a standard (known) value (p₀) is available for the expected proportion of nonconforming items, based on extensive testing or previous sampling. This example illustrates how you can specify p₀ to create an np chart.

An np chart is used to monitor the number of failing circuits in the data set CIRCUITS, which is introduced at "Creating np Charts from Count Data" . The expected proportion of failing circuits is known to be p₀=0.02. The following statements create an np chart, shown in Output 34.2.1, using p₀ to compute the control limits:

   title1 'np Chart for Failing Circuits';
   title2 'Using Data in CIRCUITS and Standard Value P0=0.02';
   symbol v=none w=3;
   proc shewhart data=circuits;
      npchart fail*batch / subgroupn = 500
                           p0        = 0.02
                           npsymbol  = np0
                           nolegend
                           needles
                           cneedles  = yellow
                           cframe    = vibg
                           cinfill   = vlibg
                           coutfill  = salmon;
      label batch = 'Batch Number'
            fail  = 'Fraction Failing';
   run;

Output 34.2.1: An np Chart with Standard Value of p₀

The chart indicates that the process is in control. The P0= option specifies p₀. The NPSYMBOL= option specifies a label for the central line indicating that the line represents a standard value. The NEEDLES option connects points to the central line with vertical needles. The NOLEGEND option suppresses the default legend for subgroup sample sizes. Labels for the vertical and horizontal axes are provided with the LABEL statement. For details concerning axis labeling, see "Axis Labels" .

Alternatively, you can specify p₀ using the variable _P_ in a LIMITS= data set, as follows:

   data climits;
      length _var_ _subgrp_ _type_ $8;
      _p_      = 0.02;
      _subgrp_ = 'batch';
      _var_    = 'fail';
      _type_   = 'STANDARD';
      _limitn_ = 500;

   proc shewhart data=circuits limits=climits;
      npchart fail*batch / subgroupn = 500
                           npsymbol  = np0
                           nolegend
                           needles;
      label batch ='Batch Number'
            fail  ='Fraction Failing';
   run;

The bookkeeping variable _TYPE_ indicates that _P_ has a standard value. The chart produced by these statements is identical to the chart in Output 34.2.1.

Chapter Contents
Previous
Next
Top