The MEANS Procedure

Example 11: Identifying the Top Three Extreme Values with the Output Statistics

Procedure features:

PROC MEANS statement option:

NOPRINT

CLASS statement

OUTPUT statement options:

	statistic keywords
	AUTONAME
	IDGROUP
	INHERIT

Other features:

RENAME = data set option

Data set:

CHARITY

This example

suppresses the display of default statistics
analyzes the data for the one-way combination of the class variables and across all observations
outputs the total and average amount of money raised to new variables
outputs to new variables the top three amounts of money raised, the names of the three students who raised the money, the years when it occurred, and the schools the students attended
automatically resolves conflicts in the variable names when names are assigned to the new variables in the output data set
assigns a format to the variable analysis so that the statistics that are computed from this variable inherit the attribute in the output data set
renames the _FREQ_ variable in the output data set
displays the output data set.

Program

options nodate pageno=1 linesize=80 pagesize=60;

 proc format;
   value yrFmt . = " All";
   value $schFmt ' ' = "All    ";
run;

proc means data=Charity noprint;

   class School Year;

   types () school year;

   var moneyraised;

   output out=top3list(rename=(_freq_=NumberStudents)) sum= mean= 
          idgroup(max(moneyraised) out[3](moneyraised name school year)=)
           /inherit autoname;

   format year yrfmt. school $schfmt.
          moneyraised dollar8.2;
  run;

proc print data=top3list;
   title1 'School Funding Raising Report';
   title2 'Top Three Students';
run;

Output

The output from PROC PRINT shows the top three values of MoneyRaised, the names of the students who raised these amounts, the schools the students attended, and the years when the money was raised. The first observation contains the overall results, the next three contain the results by year, and the final two contain the results by school. The missing class levels for School and Year are replaced with the value of ALL.

Chapter Contents
Previous
Next
Top of Page