Chapter Contents

Previous

Next

LIBNAME

Valid:	Anywhere
Category:	Data Access
See Also:	LIBNAME, SAS/ACCESS

LIBNAME libref <engine> 'SAS-data-library' < options > <engine/host-options>;

LIBNAME libref CLEAR | _ALL_ CLEAR;

LIBNAME libref LIST | _ALL_ LIST;

LIBNAME libref <engine> (library-specification-1 <. . . library-specification-n>) < options > ;

Arguments

libref

is a shortcut name or a "nickname" for the aggregate storage location where your SAS files are stored. It is any SAS name when you are assigning a new libref. When you are disassociating a libref from a SAS data library or when listing attributes, specify a libref that was previously assigned.

Tip:	The association between a libref and a SAS data library lasts only for the duration of the SAS session or until you change it or discontinue it with another LIBNAME statement.

'SAS-data-library'

must be the physical name for the SAS data library. The physical name is the name that is recognized by the operating environment. Enclose the physical name in single or double quotation marks.

Operating Environment Information:    For details on specifying the physical names of files, see the SAS documentation for your operating environment.  

In some operating environments, you can use an operating environment command, the LIBNAME statement, or the LIBNAME function to associate the libref with the SAS data library. In others, you must use an operating environment command. See the SAS documentation for your operating environment for more information.

library-specification

is two or more SAS data libraries, specified by physical names, previously-assigned librefs, or a combination of the two. Separate each specification with either a blank or a comma and enclose the entire list in parentheses.

'SAS-data-library'

the physical name of a SAS data library, enclosed in quotation marks.

libref

is the name of a previously-assigned libref.

Restriction:	When concatenating libraries, you cannot specify options that are specific to an engine or an operating environment.
Featured in:	Logically Concatenating SAS Data Libraries
See Also:	Rules for Library Concatenation

engine

is an engine name.

Tip:	Generally, SAS automatically determines the appropriate engine to use for accessing the files in the library. If you want to create a new library with an engine other than the default engine, you can override the automatic selection.
See:	For a list of valid engines, see the SAS documentation for your operating environment. For background information about engines, see SAS Language Reference: Concepts.

CLEAR

disassociates one or more currently assigned librefs.

Tip:	Specify libref to disassociate a single libref. Specify _ALL_ to disassociate all currently assigned librefs.

_ALL_

specifies that the CLEAR or LIST argument applies to all currently-assigned librefs.

LIST

writes the attributes of one or more SAS data libraries to the SAS log.

Tip:	Specify libref to list the attributes of a single SAS data library. Specify _ALL_ to list the attributes of all SAS data libraries that have librefs in your current session.

Options

ACCESS=READONLY|TEMP

READONLY	assigns a read-only attribute to an entire SAS data library. SAS will not allow you to open a data set in the library in order to update information or write new information.
TEMP	indicates that the SAS data library be treated as a scratch library. That is, the system will not consume CPU cycles to ensure that the files in a TEMP library do not become corrupted. Tip: Use ACCESS=TEMP to save resources only when the data are recoverable.

Operating Environment Information:    Some operating environments support LIBNAME statement options that have similar functions to the ACCESS= option. See the SAS documentation for your operating environment.  

OUTREP=default-format

specifies the default format for the SAS data library that is specified. New data sets that are stored in this SAS data library are written in this format. Existing data sets that are written to the library are given the new format. Values for OUTREP= are

MVS CMS VSE VAX_VMS ALPHA_VMS ALPHA_OSF SOLARIS HP_UX RS_6000_AIX WINDOWS OS2 MAC

TRANTAB=translation-table

specifies the translation table to use for character conversions. When any data set in a format foreign to the host is written to the specified SAS data library, SAS uses the specified translation table.

Interaction:

A translation table that is specified with the TRANTAB= data set option for a specific data set overrides the translation table that is specified with the TRANTAB= option in the LIBNAME statement for an entire library.

Operating Environment Information:    For a list of valid specifications, see the SAS documentation for your operating environment.  

Engine-Host-Options

engine-host-options

are one or more options listed in the general form keyword=value.

Operating Environment Information:    For a list of valid specifications, see the SAS documentation for your operating environment.  

Restriction:

When concatenating libraries, you cannot specify options that are specific to an engine or an operating environment.

Details

Associating a Libref with a SAS Data Library

The association between a libref and a SAS data library lasts only for the duration of the SAS session or until you change it or discontinue it with another LIBNAME statement. The simplest form of the LIBNAME statement specifies only a libref and the physical name of a SAS data library:

Syntax

LIBNAME libref 'SAS-data-library';

See Assigning and Using a Libref.

An engine specification is usually not necessary. If the situation is ambiguous, SAS uses the setting of the ENGINE= system option to determine the default engine. If all data sets in the library are associated with a single engine, SAS uses that engine as the default. In either situation, you can override the default by specifying another engine with the ENGINE= option:

Syntax

LIBNAME libref engine 'SAS-data-library' <options > <engine/host-options>;

Operating Environment Information:    Using the LIBNAME statement requires host-specific information. See the SAS documentation for your operating environment before using this statement.   

Disassociating a libref from a SAS Data Library

To disassociate a libref from a SAS data library, use a LIBNAME statement, specifying the libref and the CLEAR option. You can clear a single, specified libref or all current librefs.

Syntax

LIBNAME libref CLEAR | _ALL_ CLEAR;

Writing SAS Data Library Attributes to the SAS Log

Use a LIBNAME statement to write the attributes of one or more SAS data libraries to the SAS log. Specify libref to list the attributes of one SAS data library; use _ALL_ to list the attributes of all SAS data libraries that have been assigned librefs in your current SAS session.

Syntax

LIBNAME libref LIST | _ALL_ LIST;

Concatenating SAS Data Libraries

When you logically concatenate two or more SAS data libraries, you can reference them all with one libref. You can specify a library with its physical pathname or its previously assigned libref.

Syntax

LIBNAME libref <engine> (library-specification-1 <. . . library-specification-n>) < options > ;

In the same LIBNAME statement you can use any combination of specifications: librefs, physical pathnames, or a combination of librefs and pathnames. See Logically Concatenating SAS Data Libraries.

Implicitly Concatenating SAS Catalogs

When you logically concatenate two or more SAS data libraries, you also implicitly concatenate the SAS catalogs that have the same name. For example, if three SAS data libraries each contain a catalog named CATALOG1, then when you concatenate them, you implicitly create a catalog concatenation for the catalogs that have the same name. See Implicitly Concatenating SAS Catalogs.

Syntax

LIBNAME libref <engine> (library-specification-1 <. . . library-specification-n>) < options > ;

Rules for Library Concatenation

After you create a library concatenation, you can specify the libref in any context that accepts a simple (nonconcatenated) libref. These rules determine how SAS files (that is, members of SAS libraries) are located among the concatenated libraries:

1. When a SAS file is opened for input or update, the concatenated libraries are searched and the first occurrence of the specified file is used.

2. When a SAS file is opened for output, it is created in the first library that is listed in the concatenation.

   Note:    A new SAS file is created in the first library even if there is a file with the same name in another part of the concatenation.  

3. When you delete or rename a SAS file, only the first occurrence of the file is affected.

4. Any time a list of SAS files is displayed, only one occurrence of a file name is shown.

   Note:    Even if the name occurs multiple times in the concatenation, only the first occurrence is shown.  

5. A SAS file that is logically connected to another file (such as an index to a data set) is listed only if the parent file resides in that same library. For example, if library ONE contains A.DATA, and library TWO contains A.DATA and A.INDEX, only A.DATA from library ONE is listed. (See rule 4.)

6. If any library in the concatenation is sequential, then all of the libraries are treated as sequential.

7. The attributes of the first library that is specified determine the attributes of the concatenation. For example, if the first SAS data library that is listed is "read only", then the entire concatenated library is "read only".

8. If you specify any options or engines, they apply only to the libraries that you specified with the complete physical name, not to any library that you specified with a libref.

9. If you alter a libref after it has been assigned in a concatenation, it will not affect the concatenation.

Comparisons

• Use the LIBNAME statement to reference a SAS data library. Use the FILENAME statement to reference an external file. Use the LIBNAME, SAS/ACCESS statement to access DBMS tables.

• Use the CATNAME statement to explicitly concatenate SAS catalogs. Use the LIBNAME statement to implicitly concatenate SAS catalogs. The CATNAME statement allows you to specify the names of the catalogs that you want to concatenate. The LIBNAME statement concatenates all like-named catalogs in the specified SAS data libraries.

Examples

Example 1: Assigning and Using a Libref

This example assigns the libref SALES to an aggregate storage location that is specified in quotation marks as a physical pathname. The DATA step creates SALES.QUARTER1 and stores it in that location. The PROC PRINT step references it by its two-level name, SALES.QUARTER1.

   libname sales 'SAS-data-library';

   data sales.quarter1;
      infile 'your-input-file;  
      input salesrep $20. +6 jansales febsales 
            marsales;
   run;

   proc print data=sales.quarter1;
   run;

Example 2: Logically Concatenating SAS Data Libraries

• This example concatenates three SAS data libraries by specifying the physical filename of each:

  
     libname allmine ('path-1' 'path-2'
                     'path-3');
   

• This example assigns librefs to two SAS data libraries, one that contains Version 6 SAS files and one that contains Version 7 SAS files. This technique is useful for updating your files and applications from Version 6 to Version 7, while allowing you to have convenient access to both sets of files:

  
     libname v6 'path-to-v6-library';
     libname v7 'path-to-v7-library';
     libname allmine (v6 v7);
   

• This example shows that you can specify both librefs and physical filenames in the same concatenation specification:

  
     libname allmine (v6 v7 'some-path');

Example 3: Implicitly Concatenating SAS Catalogs

This example concatenates three SAS data libraries by specifying the physical filename of each and assigns the libref ALLMINE to the concatenated libraries:

   libname allmine ('path-1' 'path-2'
                   'path-3');
 

If each library contains a SAS catalog named MYCAT, then using ALLMINE.MYCAT as a libref.catref provides access to the catalog entries that are stored in all three catalogs named MYCAT. To logically concatenate SAS catalogs with different names, see CATNAME.

Example 4: Storing Data Sets with One-Level Names Permanently

If you want the convenience of specifying only a one-level name for permanent, not temporary, SAS files, use the USER= system option. This example stores data set QUARTER1 permanently without using a LIBNAME statement first to assign a libref to a storage location:

   options user='SAS-data-library';

   data quarter1;
      infile 'your-input-file;  
      input salesrep $20. +6 jansales febsales 
            marsales;
   run;

   proc print data=quarter1;
   run;

	Statements: FILENAME LIBNAME, SAS/ACCESS CATNAME for a discussion of explicitly concatenating SAS catalogs
	System Option: USER=

Chapter Contents

Previous

Next

Top of Page

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.