RZLIND Call

Language Reference

RZLIND Call

computes rank deficient linear least-squares solutions, complete orthogonal factorization, and Moore-Penrose inverses

CALL RZLIND( lindep, rup, bup, r<, sing><, b>);

The RZLIND subroutine returns the following values:

lindep: is a scalar giving the number of linear dependencies that are recognized in R (number of zeroed rows in rup[n,n]).
rup: is the updated n ×n upper triangular matrix R containing zero rows corresponding to zero recognized diagonal elements in the original R.
bup: is the n ×p matrix B of right-hand sides that is updated simultaneously with R. If b is not specified, bup is not accessible.

The inputs to the RZLIND subroutine are as follows:

r: specifies the n ×n upper triangular matrix R. Only the upper triangle of r is used; the lower triangle may contain any information.
sing: is an optional scalar specifying a relative singularity criterion for the diagonal elements of R. The diagonal element r_ii is considered zero if $r_{ii}\leq sing\Vert{r}_i\Vert$ ,where |r_i| is the Euclidean norm of column r_i of R. If the value provided for sing is not positive, the default value sing $= 1000\epsilon$ is used, where $\epsilon$ is the relative machine precision.
b: specifies the optional n ×p matrix B of right-hand sides that have to be updated or downdated simultaneously with R.

The singularity test used in the RZLIND subroutine is a relative test using the Euclidean norms of the columns r_i of R. The diagonal element r_ii is considered as nearly zero (and the i^th row is zeroed out) if the following test is true:

$r_{ii} \leq {sing} \Vert r_i \Vert, { where } \Vert r_i \Vert = \sqrt{r_i^' r_i}$

Providing an argument sing $\leq 0$ is the same as omitting the argument sing in the RZLIND call. In this case, the default is sing $= 1000\epsilon$ , where $\epsilon$ is the relative machine precision. If R is computed by the QR decomposition A = QR, then the Euclidean norm of column i of R is the same (except for rounding errors) as the Euclidean norm of column i of A.

Consider the following possible application of the RZLIND subroutine. Assume that you want to compute the upper triangular Cholesky factor R of the n ×n positive semidefinite matrix A' A,

$A^' A= R^' R { where } A\in {\cal R}^{m x n}, {\rm rank}(A)=r, r \leq n \leq m$

The Cholesky factor R of a positive definite matrix A' A is unique (with the exception of the sign of its rows). However, the Cholesky factor of a positive semidefinite (singular) matrix A' A can have many different forms.

In the following example, A is a 12 ×8 matrix with linearly dependent columns a₁ = a₂ + a₃ + a₄ and a₁ = a₅ + a₆ + a₇ with r=6, n=8, and m=12.

   proc iml;
      a = {1 1 0 0 1 0 0,
           1 1 0 0 1 0 0,
           1 1 0 0 0 1 0,
           1 1 0 0 0 0 1,
           1 0 1 0 1 0 0,
           1 0 1 0 0 1 0,
           1 0 1 0 0 1 0,
           1 0 1 0 0 0 1,
           1 0 0 1 1 0 0,
           1 0 0 1 0 1 0,
           1 0 0 1 0 0 1,
           1 0 0 1 0 0 1};
      a = a || uniform(j(12,1,1));
      aa = a` * a;
      m = nrow(a); n = ncol(a);

Applying the ROOT function to the coefficient matrix A' A of the normal equations,

   r1 = root(aa);
   ss1 = ssq(aa - r1` * r1);
   print ss1 r1 [format=best6.];

generates an upper triangular matrix R₁ where linearly dependent rows are zeroed out, and you can verify that A' A = R'₁ R₁.

Applying the QR subroutine with column pivoting on the original matrix A yields a different result, but you can also verify A' A = R'₂ R₂ after pivoting the rows and columns of A' A:

   ord = j(n,1,0);
   call qr(q,r2,pivqr,lindqr,a,ord);
   ss2 = ssq(aa[pivqr,pivqr] - r2` * r2);
   print ss2 r2 [format=best6.];

Using the RUPDT subroutine for stepwise updating of R by the m rows of A will finally result in an upper triangular matrix R₃ with n-r nearly zero diagonal elements. However, other elements in rows with nearly zero diagonal elements can have significant values. The following statements verify that A' A = R'₃ R₃,

   r3 = shape(0,n,n);
   call rupdt(rup,bup,sup,r3,a);
   r3 = rup;
   ss3 = ssq(aa - r3` * r3);
   print ss3 r3 [format=best6.];

The result R₃ of the RUPDT subroutine can be transformed into the result R₁ of the ROOT function by left applications of Givens rotations to zero out the remaining significant elements of rows with small diagonal elements. Applying the RZLIND subroutine on the upper triangular result R₃ of the RUPDT subroutine will generate a Cholesky factor R₄ with zero rows corresponding to diagonal elements that are small, giving the same result as the ROOT function (except for the sign of rows) if its singularity criterion recognizes the same linear dependencies.

   call rzlind(lind,r4,bup,r3);
   ss4 = ssq(aa - r4` * r4);
   print ss4 r4 [format=best6.];

Consider the rank-deficient linear least-squares problem:

$\min_{x} \Vert A{x}- b\Vert^2 { where } A\in {\cal R}^{m x n}, {\rm rank}(A)=r, r \leq n \leq m$

For r=n, the optimal solution, $\hat{x}$ , is unique; however, for r<n, the rank-deficient linear least-squares problem has many optimal solutions, each of which has the same least-squares residual sum of squares:

${ss} = (A\hat{x} - b)^'(A\hat{x} - b)$

The solution of the full rank problem, r=n, is illustrated in the QR call. The following list shows several solutions to the singular problem. This example uses the 12 ×8 matrix from the preceding section and generates a new column vector b. The vector b and the matrix A are shown in the output.

   b = uniform(j(12,1,1));
   ab = a` * b;
   print b a [format=best6.];

Each entry in the following list solves the rank-deficient linear least-squares problem. Note that while each method minimizes the residual sum of squares, not all of the given solutions are of minimum Euclidean length.

Use the singular value decomposition of A, given by A = UDV'. Take the reciprocals of significant singular values and set the small values of D to zero.

         call svd(u,d,v,a);
         t = 1e-12 * d[1];
         do i=1 to n;
            if d[i] < t then d[i] = 0.;
            else d[i] = 1. / d[i];
         end;
         x1 = v * diag(d) * u` * b;
         len1 = x1` * x1;
         ss1 = ssq(a * x1 - b);
         x1 = x1`;
         print ss1 len1, x1 [format=best6.];

The solution $\hat{x}_1$ obtained by singular value decomposition, $\hat{x}_1 = V{D}^- U^' b/4$ , is of minimum Euclidean length.

Use QR decomposition with column pivoting:

$A{{\Pi}}= Q{R}= [ Y& Z ] [ R_1 & R_2 \ 0 & 0 ] = Y[ R_1 & R_2 ]$

Set the right part R₂ to zero and invert the upper triangular matrix R₁ to obtain a generalized inverse R^- and an optimal solution $\hat{x}_2$ :

$R^- = [ R_1^{-1} \ 0 ] \hspace*{0.25in} \hat{x}_2 = {{\Pi}}R^- Y^' b$

         ord = j(n,1,0);
         call qr(qtb,r2,pivqr,lindqr,a,ord,b);
         nr = n - lindqr;
         r = r2[1:nr,1:nr];
         x2 = shape(0,n,1);
         x2[pivqr] = trisolv(1,r,qtb[1:nr]) // j(lindqr,1,0.);
         len2 = x2` * x2;
         ss2 = ssq(a * x2 - b);
         x2 = x2`;
         print ss2 len2, x2 [format=best6.];

Note that the residual sum of squares is minimal, but the solution $\hat{x}_2$ is not of minimum Euclidean length.

Use the result R₁ of the ROOT function on this page to obtain the vector piv indicating the zero rows in the upper triangular matrix R₁:

         r1 = root(aa);
         nr = n - lind;
         piv = shape(0,n,1);
         j1 = 1; j2 = nr + 1;
         do i=1 to n;
            if r1[i,i] ^= 0 then do;
               piv[j1] = i; j1 = j1 + 1;
            end;
            else do;
               piv[j2] = i; j2 = j2 + 1;
            end;
         end;

Now compute $\hat{x}_3$ by solving the equation $\hat{x}_3 = R^{-1}R^{-' A^' b$ .

         r  = r1[piv[1:nr],piv[1:nr]];
         x  = trisolv(2,r,ab[piv[1:nr]]);
         x  = trisolv(1,r,x);
         x3 = shape(0,n,1);
         x3[piv] = x // j(lind,1,0.);
         len3 = x3` * x3;
         ss3  = ssq(a * x3 - b);
         x3 = x3`;
         print ss3 len3, x3 [format=best6.];

Note that the residual sum of squares is minimal, but the solution $\hat{x}_3$ is not of minimum Euclidean length.

Use the result R₃ of the RUPDT call on this page and the vector piv (obtained in the previous solution), which indicates the zero rows of upper triangular matrices R₁ and R₃. After zeroing out the rows of R₃ belonging to small diagonal pivots, solve the system $\hat{x}_4 = R^{-1}Y^' b$ .

         r3 = shape(0,n,n);
         qtb = shape(0,n,1);
         call rupdt(rup,bup,sup,r3,a,qtb,b);
         r3 = rup; qtb = bup;
         call rzlind(lind,r4,bup,r3,,qtb);
         qtb = bup[piv[1:nr]];
         x  = trisolv(1,r4[piv[1:nr],piv[1:nr]],qtb);
         x4 = shape(0,n,1);
         x4[piv] = x // j(lind,1,0.);
         len4 = x4` * x4;
         ss4 = ssq(a * x4 - b);
         x4 = x4`;
         print ss4 len4, x4 [format=best6.];

Since the matrices R₄ and R₁ are the same (except for the signs of rows), the solution $\hat{x}_4$ is the same as $\hat{x}_3$ .

Use the result R₄ of the RZLIND call in the previous solution, which is the result of the first step of complete QR decomposition, and perform the second step of complete QR decomposition. The rows of matrix R₄ can be permuted to the upper trapezoidal form
$[ \hat{R} & T\ 0 & 0 ],$
where is nonsingular and upper triangular and T is rectangular. Next, perform the second step of complete QR decomposition with the lower triangular matrix
$[ \hat{R}^' \ T^' ] = \bar{Y} [ \bar{R} \ 0 ],$
which leads to the upper triangular matrix .
```
         r = r4[piv[1:nr],]`;
         call qr(q,r5,piv2,lin2,r);
         y  = trisolv(2,r5,qtb);
         x5 = q * (y // j(lind,1,0.));
         len5 = x5` * x5;
         ss5 = ssq(a * x5 - b);
         x5 = x5`;
         print ss5 len5, x5 [format=best6.];
```
The solution $\hat{x}_5$ obtained by complete QR decomposition has minimum Euclidean length.

Perform both steps of complete QR decomposition. The first step performs the pivoted QR decomposition of A,

$A{{\Pi}}= Q{R}= Y[ R\ 0 ] = Y[ \hat{R}T\ 0 ]$

where $\hat{R}$ is nonsingular and upper triangular and T is rectangular. The second step performs a QR decomposition as described in the previous method. This results in

$A{{\Pi}}= Y[ \bar{R}^' & 0 \ 0 & 0 ] \bar{Y}^'$

where $\bar{R}^'$ is lower triangular.

         ord  = j(n,1,0);
         call qr(qtb,r2,pivqr,lindqr,a,ord,b);
         nr   = n - lindqr;
         r    = r2[1:nr,]`;
         call qr(q,r5,piv2,lin2,r);
         y    = trisolv(2,r5,qtb[1:nr]);
         x6   = shape(0,n,1);
         x6[pivqr] = q * (y // j(lindqr,1,0.));
         len6 = x6` * x6;
         ss6  = ssq(a * x6 - b);
         x6   = x6`;
         print ss6 len6, x6 [format=best6.];

The solution $\hat{x}_6$ obtained by complete QR decomposition has minimum Euclidean length.

Perform complete QR decomposition with the QR and LUPDT calls:

         ord  = j(n,1,0);
         call qr(qtb,r2,pivqr,lindqr,a,ord,b);
         nr   = n - lindqr;
         r    = r2[1:nr,1:nr]`; z = r2[1:nr,nr+1:n]`;
         call lupdt(lup,bup,sup,r,z);
         rd   = trisolv(3,lup,r2[1:nr,]);
         rd   = trisolv(4,lup,rd);
         x7   = shape(0,n,1);
         x7[pivqr] = rd` * qtb[1:nr,];
         len7 = x7` * x7;
         ss7  = ssq(a * x7 - b);
         x7 = x7`;
         print ss7 len7, x7 [format=best6.];

The solution $\hat{x}_7$ obtained by complete QR decomposition has minimum Euclidean length.

Perform complete QR decomposition with the RUPDT, RZLIND, and LUPDT calls:

         r3 = shape(0,n,n);
         qtb = shape(0,n,1);
         call rupdt(rup,bup,sup,r3,a,qtb,b);
         r3 = rup; qtb = bup;
         call rzlind(lind,r4,bup,r3,,qtb);
         nr = n - lind; qtb = bup;
         r = r4[piv[1:nr],piv[1:nr]]`;
         z = r4[piv[1:nr],piv[nr+1:n]]`;
         call lupdt(lup,bup,sup,r,z);
         rd = trisolv(3,lup,r4[piv[1:nr],]);
         rd = trisolv(4,lup,rd);
         x8 = shape(0,n,1);
         x8 = rd` * qtb[piv[1:nr],];
         len8 = x8` * x8;
         ss8 = ssq(a * x8 - b);
         x8 = x8`;
         print ss8 len8, x8 [format=best6.];

The solution $\hat{x}_8$ obtained by complete QR decomposition has minimum Euclidean length. The same result can be obtained with the APPCORT or COMPORT call.

You can use various methods to compute the Moore-Penrose inverse A^- of a rectangular matrix A using orthogonal methods. The entries in the following list find the Moore-Penrose inverse of the matrix A shown on this page.

Use the GINV operator. The GINV operator in IML uses the singular decomposition A = UDV'. The result A^- = VD^- U' should be identical to the result given by the next solution.

         ga = ginv(a);
         t1 = a * ga; t2 = t1`;
         t3 = ga * a; t4 = t3`;
         ss1 = ssq(t1 - t2) + ssq(t3 - t4) +
               ssq(t1 * a - a) + ssq(t3 * ga - ga);
         print ss1, ga [format=best6.];

Use singular value decomposition. The singular decomposition A = UDV' with U'U = I_m, D = diag(d_i), and V'V = VV' = I_n, can be used to compute , with and
$d_i^\dagger = \{ 0 & {where } d_i \leq \epsilon \ 1/d_i & {otherwise} .$
The result A^- should be the same as that given by the GINV operator if the singularity criterion is selected correspondingly. Since you cannot specify the criterion for the GINV operator, the singular value decomposition approach can be important for applications where the GINV operator uses an unsuitable criterion. The slight discrepancy between the values of SS1 and SS2 is due to rounding that occurs in the statement that computes the matrix GA.
```
         call svd(u,d,v,a);
         do i=1 to n;
            if d[i] <= 1e-10 * d[1] then d[i] = 0.;
            else d[i] = 1. / d[i];
         end;
         ga = v * diag(d) * u`;
         t1 = a * ga; t2 = t1`;
         t3 = ga * a; t4 = t3`;
         ss2 = ssq(t1 - t2) + ssq(t3 - t4) +
               ssq(t1 * a - a) + ssq(t3 * ga - ga);
         print ss2;
```

Use complete QR decomposition. The complete QR decomposition

$A= Y[ \bar{R}^' & 0 \ 0 & 0 ] \bar{Y}^' {{\Pi}}^'$

where $\bar{R}^'$ is lower triangular, yields the Moore-Penrose inverse

$A^- = {{\Pi}}\bar{Y} [ \bar{R}^{-' & 0 \ 0 & 0 ] Y^'$

         ord = j(n,1,0);
         call qr(q1,r2,pivqr,lindqr,a,ord);
         nr = n - lindqr;
         q1 = q1[,1:nr]; r = r2[1:nr,]`;
         call qr(q2,r5,piv2,lin2,r);
         tt = trisolv(4,r5`,q1`);
         ga = shape(0,n,m);
         ga[pivqr,] = q2 * (tt // shape(0,n-nr,m));
         t1 = a * ga; t2 = t1`;
         t3 = ga * a; t4 = t3`;
         ss3 = ssq(t1 - t2) + ssq(t3 - t4) +
               ssq(t1 * a - a) + ssq(t3 * ga - ga);
         print ss3;

Use complete QR decomposition with QR and LUPDT:

         ord = j(n,1,0);
         call qr(q,r2,pivqr,lindqr,a,ord);
         nr = n - lindqr;
         r = r2[1:nr,1:nr]`; z = r2[1:nr,nr+1:n]`;
         call lupdt(lup,bup,sup,r,z);
         rd = trisolv(3,lup,r2[1:nr,]);
         rd = trisolv(4,lup,rd);
         ga = shape(0,n,m);
         ga[pivqr,] = rd` * q[,1:nr]`;
         t1 = a * ga; t2 = t1`;
         t3 = ga * a; t4 = t3`;
         ss4 = ssq(t1 - t2) + ssq(t3 - t4) +
               ssq(t1 * a - a) + ssq(t3 * ga - ga);
         print ss4;

Use complete QR decomposition with RUPDT and LUPDT:

         r3 = shape(0,n,n);
         y = i(m); qtb = shape(0,n,m);
         call rupdt(rup,bup,sup,r3,a,qtb,y);
         r3 = rup; qtb = bup;
         call rzlind(lind,r4,bup,r3,,qtb);
         nr = n - lind; qtb = bup;
         r = r4[piv[1:nr],piv[1:nr]]`;
         z = r4[piv[1:nr],piv[nr+1:n]]`;
         call lupdt(lup,bup,sup,r,z);
         rd = trisolv(3,lup,r4[piv[1:nr],]);
         rd = trisolv(4,lup,rd);
         ga = shape(0,n,m);
         ga = rd` * qtb[piv[1:nr],];
         t1 = a * ga; t2 = t1`;
         t3 = ga * a; t4 = t3`;
         ss5 = ssq(t1 - t2) + ssq(t3 - t4) +
               ssq(t1 * a - a) + ssq(t3 * ga - ga);
         print ss5;

Chapter Contents
Previous
Next
Top